Aminet 22/Aminet 22 (1997)(GTI - Schatztruhe)[!][Dec 1997].iso/Aminet/biz/demo/AWeb.lha/aweb30demo/Install

Text File | 1997-09-20 | 6KB | 206 lines

; $VER: Install_AWeb 3.0DEMO (2.5.97)
; Description: Installer script for AWeb-II 3.0DEMO

(set cpu (database "cpu"))
(set cpu020 (and (<> cpu "68000") (<> cpu "68010")))
(set v39 (>= (/ (getversion "exec.library" (resident)) 65536) 39))

(set awn (getversion "AWeb"))
(set awv (/ awn 65536))
(set awr (- awn (* awv 65536)))

; all strings used in this installer script
(set #need39 "This program requires OS 3.0 or later to function.")
(set #nohelp "No help available.")
(set #welcome
   (cat "AWeb-II is a fast, multithreaded World Wide Web browser for Amiga OS 3.0 or higher.\n"
      "It understands virtually all widely used HTML and has many other features.\n"
      "AWeb-II runs with a wide variety of TCP-stacks."
      ("\n\nThis installation procedure will install the AWeb-II browser version %ld.%ldDEMO on your system.\n" awv awr)
   )
)
(set #classact
   (cat "IMPORTANT\n\n"
        "This AWeb-II demo needs the ClassAct GUI package to run.\n"
        "The ClassAct package is not included in the demo archive, but is freely available "
        "from Aminet, and via ftp from:\n"
        "ftp://ftp.warped.com/pub/amiga/classact/"
   )
)

(set #destdir-prompt "Please select the directory where you want AWeb-II DEMO installed.\n(If you do not accept the default, a directory 'AWeb30DEMO' will be created there.)")
(set #destdir-help "A directory for AWeb30DEMO will be created here. By accepting the default directory, most of the files don't have to be copied.")
(set #installing "Installing ")
(set #memory-prompt "Is your Amiga equipped with more than 2MB of memory?")
(set #memory-help "AWeb-II runs on a 2MB Amiga, but needs a special setup on such a machine. If you click the 'only 2MB' button, the appropriate settings will be installed.\n\nYou can always change the settings after installation.")
(set #fonts-prompt "Do you want to install the \"times.font\" and \"courier.font\" sizes 30 and 36?")
(set #fonts-help
   (cat "In order to provide AWeb-II with a consistent set of fonts, four fonts are included "
      "in this archive, times/30, times/36, courier/30 and courier/36.\n\n"
      "Because the demo uses these fonts by default, page headers might look really awful "
      " if you don't install these fonts. It is highly recommended that you install them."
   )
)
(set #fixfonts-prompt "The FixFonts utility will be run to make the newly added fonts available.")
(set #fixfonts-help
   (cat "The FixFonts utility is needed to make the newly added fonts available to the system.\n\n"
      "If you intend to use the fonts from this archive, you are strongly encouraged to "
      "run FixFonts now.\n\n"
      "Note that running this program may take a while."
   )
)

(set #readme "Displaying the version notes readme...")
(set #bye
   (cat "In case you need help configuring or using AWeb-II DEMO, pressing the HELP key "
      "when AWeb is active will bring up the documentation.\n"
      "I hope you will enjoy using this demo and will consider purchasing the full version."
   )
)

; ---------------------------------------------------------------------------

(complete 0)

(if (not v39)
   (abort #need39)
)

(message #welcome)

(set @source-dir (pathonly @icon))

(set defdir
   (askdir
      (prompt #destdir-prompt)
      (help #destdir-help)
      (default @source-dir)
   )
)
(set @default-dest defdir)

(set nocopy (= @source-dir @default-dest))

(message #classact)

(if (not nocopy)
    (
       (set @default-dest (tackon @default-dest "AWeb30DEMO"))

       (set update-aweb (exists @default-dest))

       (if (not update-aweb)
           (makedir @default-dest
               (prompt #creating-dir @default-dest)
               (infos)
           )
       )
      (complete 10)

      (copyfiles
         (source "")
         (dest @default-dest)
         (choices "AWeb" "AWebCfg")
         (prompt #installing "AWeb")
         (infos)
      )
      (complete 20)

       (copyfiles
         (source "")
          (dest @default-dest)
         (choices "aweblib")
          (prompt #installing "AWeb")
       )
      (complete 30)

      (set cache-dir (tackon @default-dest "Cache"))
      (if (not (exists cache-dir))
         (
            (makedir cache-dir
               (prompt #creating-dir cache-dir)
               (infos)
            )
         )
      )
      (complete 40)

       (copyfiles
         (source "")
          (dest @default-dest)
         (choices "ReadMe" "Docs" "Icons" "Images")
          (prompt #installing "AWeb")
          (infos)
       )

    )
)

(complete 60)

; Only ask if fonts should be installed in expert mode
(if
   (< @user-level 2)
   (set #fonts 1)
   (set #fonts
      (askbool
         (prompt #fonts-prompt)
         (help #fonts-help)
         (choices "Yes" "No")
         (default 1)
      )
   )
)
(if
   (> #fonts 0)
   (
      (copyfiles
         (source "Fonts")
         (dest "Fonts:")
         (choices "times" "courier")
         (prompt #installing "fonts")
      )
      (run "SYS:System/FixFonts"
         (confirm)
         (prompt #fixfonts-prompt)
         (help #fixfonts-help)
      )
   )
)

(complete 80)

(set #memory
   (askbool
      (prompt #memory-prompt)
      (help #memory-help)
      (choices "More than 2MB" "Only 2MB")
      (default 1)
  )
)

(if (= #memory 0)
   (
      (makedir
         (tackon @default-dest "T")
      )
      (makedir "ENVARC:AWeb3DEMO")
      (copyfiles
         (source "2MBsettings")
         (dest "ENVARC:AWeb3DEMO")
         (all)
      )
      (copyfiles
         (source "ENVARC:AWeb3DEMO")
         (dest "ENV:AWeb3DEMO")
         (all)
      )
   )
)

(complete 100)

(run "run >NIL: SYS:Utilities/MultiView ReadMe" (prompt #readme))

(exit #bye)